home *** CD-ROM | disk | FTP | other *** search
/ Ultra Pack / UltraComputing Technology Demos and Tools.iso / java / bin / upgrade < prev   
Encoding:
Text File  |  1996-05-03  |  1.9 KB  |  47 lines
  1. #!/bin/sh
  2. # Upgrade alpha3 applets to the beta APIs. This will only
  3. # do a 80% of the work for most applets.
  4. #
  5. # Usage: upgrade < SomeAlpha3Applet.java > SomeBetaApplet.java
  6. #
  7.  
  8. /bin/sed -e "
  9.     s/^import oak\./import java./
  10.     s/^import awt\./import java.awt./
  11.     s/^import net\.www\.html\./import java.net./
  12.     /^import browser\./d
  13.     s/browser\.Applet/java.applet.Applet/g
  14.     /^class.*\<extends Applet\>/s/class/public class/
  15.     s/\<extends Applet\>/extends java.applet.Applet/
  16.     s/\([^.]\)\<Applet\>/\1java.applet.Applet/g
  17.     s/\<void mouseDown(/boolean mouseDown(java.awt.Event evt, /
  18.     s/\<void mouseUp(/boolean mouseUp(java.awt.Event evt, /
  19.     s/\<void mouseMove(/boolean mouseMove(java.awt.Event evt, /
  20.     s/\<void mouseDrag(/boolean mouseDrag(java.awt.Event evt, /
  21.     s/\<void mouseExit(/boolean mouseExit(java.awt.Event evt/
  22.     s/\<void mouseEnter(/boolean mouseEnter(java.awt.Event evt/
  23.     s/\<void keyDown(/boolean keyDown(java.awt.Event evt, /
  24.     s/\<bgColor\>/getBackground()/g
  25.     s/\.setForeground(/.setColor(/g
  26.     s/\<play(/play(getCodeBase(), /g
  27.     s/\<getImage(/getImage(getCodeBase(), /g
  28.     s/\<getAttribute(/getParameter(/g
  29.     s/\<documentURL\>/getDocumentBase()/g
  30.     s/\<appletURL\>/getCodeBase()/g
  31.     s/\<getFont(/new java.awt.Font(/g
  32.     s/\<getColor(/new java.awt.Color(/g
  33.     s/\<awt.Color\>/java.awt.Color/g
  34.     s/^[ \t]*\(Thread\.sleep(.*\)/try {\1} catch (InterruptedException e){}/
  35.     s/^[ \t]*\(Thread\.currentThread().sleep(.*\)/try {\1} catch (InterruptedException e){}/
  36.     s/\<paint3DRect(\(.*\),[ \t]*false,\([ \t]*[^)]*\))/draw3DRect(\1,\2)/g
  37.     s/\<paint3DRect(\(.*\),[ \t]*true,\([ \t]*[^)]*\))/fill3DRect(\1,\2)/g
  38.     s/\<drawImage(\(.*\))/drawImage(\1, this)/g
  39.     s/\.appendChar(/.append(/g
  40.         s/\([0-9]*\.[0-9][0-9]*\)/\1f/g
  41.         s/\([0-9.][0-9.]*[eE][0-9][0-9]*\)/\1f/g
  42.     s/\([^.]\)\<width\>/\1size().width/g
  43.         s/\([^.]\)\<height\>/\1size().height/g
  44.     s/\<getFocus()/requestFocus()/g
  45.     s/\<nowMillis\>/currentTimeMillis/g
  46. "
  47.